Com o aumento da utilização de relatórios, devido à grande quantidade de informações e a dificuldade para interpretar os dados, cada vez mais precisamos representar as informações de forma visual. O Planilhas Google possui uma função para criar gráficos em miniatura em uma célula, que pode ser usada para exibir a tendência ou evolução dos valores em cada linha ou coluna.
A função do Planilhas Google que cria gráficos em miniatura na célula é a SPARKLINE. Os tipos de gráficos em miniatura existentes são:
- Linha
- Barra
- Coluna
- Ganho e Perdas
A função SPARKLINE é representada pela fórmula:
SPARKLINE(dados; [opções])No argumento dados devemos preencher com o intervalo das células onde estão os valores para usar no gráfico.
No argumento opções, que é opcional, podemos detalhar algumas características de formatação do gráfico, como cor, espessura de linha, eixos, representação das células vazias. Quando preenchido, deve sempre usar o formato opção \ valor.
Vamos mostrar como criar gráficos em miniatura em uma planilha de marketing, com informações de visualizações e ganhos de um site.
Como criar o gráfico em miniatura
Para criar um gráfico em miniatura em uma célula da planilha, podemos digitar o nome da função diretamente na célula ou inserir a função através do menu Inserir > Função > Google > SPARKLINE.
Após inserir a função preencha o primeiro argumento dados que é obrigatório, com o intervalo das células, onde estão os valores a serem usados no gráfico.
No exemplo abaixo, temos um gráfico de linha, cujos valores estão entre as células B2 e G2 e a função SPARKLINE que está na célula H2.
Este é um gráfico do tipo Linha. Para criar os gráficos de outros tipos como barra, coluna e ganhos/perdas, devemos preencher o argumento opções da função SPARKLINE, com a opção charttype. Essa opção pode ter os valores:
- line: para o gráfico de linha, por exemplo: =SPARKLINE(A2:A10;{"charttype"\"line"}). No caso do gráfico tipo Linha, não é necessário preencher o campo charttype, porque se estiver vazio, o Planilhas Google cria o gráfico do tipo Linha, por padrão.
- bar: para o gráfico de barra, por exemplo: =SPARKLINE(A2:A10;{"charttype"\"bar"})
- column: para o gráfico de coluna, por exemplo: =SPARKLINE(A2:A10;{"charttype"\"column"})
- winloss: para o gráfico de perdas e ganhos, por exemplo: =SPARKLINE(A2:A10;{"charttype"\"winloss"})
No exemplo abaixo, temos um gráfico miniatura tipo Coluna:
Como formatar o gráfico em miniatura
Dependendo do tipo de gráfico, o Planilhas Google fornece um conjunto de opções específicas de formatação para cada gráfico. Você pode ver todas as opções na Ajuda do Planilhas Google.
Vamos destacar somente alguns exemplos de formatações, que podemos fazer em cada tipo de gráfico.
Gráfico miniatura Linha
No gráfico miniatura tipo Linha vamos alterar a cor e a espessura da linha no gráfico, usando as opções color e linewidth.
=SPARKLINE(B2:G2;{"charttype"\"line";"color"\"blue";"linewidth"\2})
ou
=SPARKLINE(B2:G2;{"charttype"\"line";"color"\"#0000ff";"linewidth"\2})
Na opção color use o nome da cor em inglês ou o código hexadecimal da cor. No primeiro exemplo, usamos "blue", no segundo exemplo, usamos "#0000ff" que representa a cor azul.
Lembre-se todas as opções de cor podem usar o nome da cor em inglês, ou o código hexadecimal da cor.
Na opção linewidth digite um número que representa a espessura da linha no gráfico, no exemplo usamos o valor 2.
Gráfico miniatura Coluna
No gráfico miniatura tipo Coluna vamos alterar a cor, usando a opção color.
=SPARKLINE(B3:G3;{"charttype"\"column";"color"\"green"})
Na opção color use o nome da cor em inglês ou código hexadecimal, no exemplo, usamos "green".
Gráfico miniatura Ganhos e Perdas
No gráfico miniatura de Ganhos e Perdas vamos alterar a cor do gráfico e a cor da coluna que possui valor negativo, usando as opções color e negcolor.
=SPARKLINE(B4:G4;{"charttype"\"winloss";"negcolor"\"red";"color"\"darkblue"})
Na opção negcolor use o nome da cor em inglês ou código hexadecimal, no exemplo, usamos "red".
Na opção color use o nome da cor em inglês ou código hexadecimal, no exemplo, usamos "darkblue".
Gráfico miniatura Barra
No gráfico miniatura tipo Barra vamos alterar a cor das barras, usando as opções color1 e color2.
=SPARKLINE(B5:G5;{"charttype"\"bar";"color1"\"blue";"color2"\"yellow"})
As opções color1 e color2 definem as cores da primeira e segunda cor usadas no gráfico. No exemplo, usamos as cores azul e amarelo.
Como exibir células vazias no gráfico em miniatura
Se existirem células vazias no meio dos dados da planilha, podemos definir como o gráfico vai apresentar a informação da célula vazia. Nesse caso use a opção empty, que pode receber os valores zero, para classificar a célula vazia como se tivesse um valor numérico zero, ou ignore, para ignorar a célula vazia.
=SPARKLINE(B2:G2;{"charttype"\"line";"empty"\"ignore"})
No exemplo, usamos a opção empty como ignore.
Agora que você viu como criar e formatar gráficos em miniatura no Planilhas Google, pode melhorar a apresentação visual das informações em suas planilhas, incluindo os gráficos, para facilitar a compreensão da evolução ou tendência dos dados.
